update PKGBUILD

PKGBUILD

@@ -1,37 +1,65 @@
-# Maintainer: wowario <wowario at protonmail dot com>
-# Contributor: wowario <wowario at protonmail dot com>
+# Maintainer: wowario <wowario[at]protonmail[dot]com>
 
-pkgbase=('wownero-git')
-pkgname=('wownero-git')
-pkgver=v0.6.1.1.r2.9afbcfb7
+pkgname=wownero-git
+pkgver=0.8.0.0
 pkgrel=1
-pkgdesc="a fairly launched privacy-centric meme coin with no premine and a finite supply"
-license=('custom:Cryptonote')
+pkgdesc="Wownero: a fairly launched privacy-centric meme coin with no premine and a finite supply"
+license=('BSD')
 arch=('x86_64')
-url="http://wownero.org/"
-depends=('openssl' 'zeromq' 'libpgm' 'unbound' 'libsodium')
+url="https://wownero.org/"
+depends=('boost-libs' 'libunwind' 'openssl' 'readline' 'zeromq' 'pcsclite' 'hidapi' 'protobuf')
 makedepends=('git' 'cmake' 'boost')
-provides=('wownero-git')
+source=(
+    "${pkgname}"::"git+https://github.com/wownero/wownero#tag=v${pkgver}"
+    "git+https://github.com/monero-project/unbound.git"
+    "git+https://github.com/monero-project/miniupnp.git"
+    "git+https://github.com/Tencent/rapidjson.git"
+    "git+https://github.com/trezor/trezor-common.git"
+    "git+https://github.com/wownero/RandomWOW.git"
+    "wownero.sysusers"
+    "wownero.tmpfiles")
+sha512sums=('SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP'
+            'SKIP')
 
-source=("${pkgname}"::"git+https://github.com/wownero/wownero")
-
-sha256sums=('SKIP')
-
-pkgver() {
-    cd "$srcdir/$pkgname"
-    git describe --long --tags | sed 's/\([^-]*-\)g/r\1/;s/-/./g'
+prepare() {
+  cd "${pkgname}"
+  git submodule init
+  git config submodule.external/unbound.url "$srcdir/unbound"
+  git config submodule.external/miniupnp.url "$srcdir/miniupnp"
+  git config submodule.external/rapidjson.url "$srcdir/rapidjson"
+  git config submodule.external/trezor-common.url "$srcdir/trezor-common"
+  git config submodule.external/RandomWOW.url "$srcdir/RandomWOW"
+  git submodule update
 }
 
 build() {
-  cd "${srcdir}/${pkgname}"
-  USE_SINGLE_BUILDDIR=1 make
+  cd "${pkgname}"
+  mkdir -p build && cd build
+  cmake -D BUILD_TESTS=OFF -D CMAKE_BUILD_TYPE=release -D ARCH=default ../
+  make
 }
 
-package_wownero-git() {
-  install -Dm644 "${srcdir}/${pkgname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
-  install -Dm644 "${srcdir}/${pkgname}/utils/conf/wownerod.conf" "${pkgdir}/etc/wownerod.conf"
-  install -Dm644 "${srcdir}/${pkgname}/utils/systemd/wownerod.service" "${pkgdir}/usr/lib/systemd/system/wownerod.service"
-  install -Dm755 "${srcdir}/${pkgname}/build/release/bin/wownerod" "${pkgdir}/usr/bin/wownerod"
-  install -Dm755 "${srcdir}/${pkgname}/build/release/bin/wownero-wallet-cli" "${pkgdir}/usr/bin/wownero-wallet-cli"
-  install -Dm755 "${srcdir}/${pkgname}/build/release/bin/wownero-wallet-rpc" "${pkgdir}/usr/bin/wownero-wallet-rpc"
+package() {
+  backup=('etc/wownerod.conf')
+
+  cd "${pkgname}"
+  install -Dm644 "LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
+
+  install -Dm644 "utils/conf/wownerod.conf" "${pkgdir}/etc/wownerod.conf"
+  install -Dm644 "utils/systemd/wownerod.service" "${pkgdir}/usr/lib/systemd/system/wownerod.service"
+  install -Dm644 "../wownero.sysusers" "${pkgdir}/usr/lib/sysusers.d/wownero.conf"
+  install -Dm644 "../wownero.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/wownero.conf"
+
+  install -Dm755 "build/bin/wownero-wallet-cli" \
+                 "build/bin/wownero-wallet-rpc" \
+                 "build/bin/wownerod" \
+                 -t "${pkgdir}/usr/bin"
 }
+
+# vim: ts=2 sw=2 et: